Figures de l'espace : placement des labels

N'oubliez pas de consulter les sujets avant de poser votre question, merci.

Figures de l'espace : placement des labels

Messagepar Fabrice » 15 Mai 2021 16:34

Bonjour Patrick,
J'ai besoin de faire un nombre important de figures pour illustrer un cours ; la remise en route avec TeXgraph a été un peu longue ! Je trouve le résultat correct mais pas tout à fait fidèle à l'image (je sais, je suis un "perfectionniste").
Notamment avec le placement des labels (j'ai ajouté le package esvect dans tes fichiers de compilation) : je tâtonne beaucoup trop !
Merci.
Fabrice

Code: Tout sélectionner
[
view(-7,7,-7,7),Marges(0,0,0,0),size(8),
view3D(-5,5,-5,5,-5,5),
A:=M(0,0,0), B:=M(1,2,0), C:=M(-2,1,0),
vec_n:=[A,5*vecK], vec_u:=[A,B],vec_v:=[A,C],
p:=[M(0,0,0),vecK],
D:=Copy(getplan(p),3,2),
   Build3D(
    bdPlan(p,[color:=aqua, opacity:=0.6,border:=1,bordercolor:=blue,width=10,
              contrast:=0.125,scale:=1]),
    bdLine(vec_u ,[color:=firebrick, arrows:=1, width:=10]),
    bdLine(vec_v ,[color:=firebrick, arrows:=1, width:=10]),
    bdLine(vec_n ,[color:=firebrick, arrows:=1, width:=10]),
    bdAngleD(A+vecK,A,B, 0.4),
    bdAngleD(A+vecK,A,C, 0.4),
    bdLabel(A+3*vecK,"$\vv{n}$",[labelpos:=[0.5,0.75+i],color:=firebrick,above:=1]),
    bdLabel(B,"$\vv{u}$",[labelpos:=[0.3,-3-2*i],color:=firebrick,above:=1]),
    bdLabel(C,"$\vv{v}$",[labelpos:=[0.3,-2-2.25*i],color:=firebrick,above:=1]),
    bdLabel(D,"$\mathscr{P}$", [labelpos:=[0.75,1+0.25*i], above:=1]),
   ),
    Display3D(),
]             


Image
Fabrice
 
Messages: 139
Inscription: 14 Août 2009 12:22

Re: Figures de l'espace : placement des labels

Messagepar P.Fradin » 15 Mai 2021 18:03

Bonjour Fabrice,

Puisque tu veux mettre les labels par dessus ( option above:=1), autant les afficher en dehors de la scène 3D, après celle-ci.
Code: Tout sélectionner
[
    view(-7,7,-7,7),Marges(0,0,0,0),size(8),
    view3D(-5,5,-5,5,-5,5),
    A:=M(0,0,0), B:=M(1,2,0), C:=M(-2,1,0), E:=A+5*vecK,
    vec_n:=E-A, vec_u:=B-A, vec_v:=C-A,
    p:=[M(0,0,0),vecK],
    D:=Copy(getplan(p),3,2),
       Build3D(
        bdPlan(p,[color:=aqua, opacity:=0.6,border:=1,
            bordercolor:=blue,width=10, contrast:=0.125,scale:=1]),
        bdLine([B,A,C] ,[color:=firebrick, arrows:=2, width:=10]),
        bdLine([A,E] ,[color:=firebrick, arrows:=1, width:=10]),
        bdAngleD(A+vecK,A,B, 0.4, [color:=navy]),
        bdAngleD(A+vecK,A,C, 0.4, [color:=navy]),
       ),
        Display3D(),
        //affichage en 2D des labels par dessus la scène
        draw("label",
          "$\vv{n}$",[anchor:=Proj3D(A+4*vecK), labeldir:= "E",labelsep:=0.1,Color:=firebrick],
          "$\vv{v}$",[anchor:=Proj3D(A+0.8*vec_v), labeldir:="SE",labelsep:=0.1],
          "$\vv{u}$",[anchor:=Proj3D(A+0.6*vec_u), labeldir:="SO"],
          "$\mathscr{P}$", [anchor:=Proj3D(D), labeldir:=[0.7,1+i/2], Color:=blue]
        ),
    ]

planFab.png
planFab.png (8.87 Kio) Consulté 3452 fois


Je ne sais pas si tu cherches à reproduire à l'identique, donc je n'ai pas modifié les couleurs et les tailles/
P.Fradin
Avatar de l’utilisateur
P.Fradin
Administrateur du site
 
Messages: 1887
Inscription: 29 Oct 2008 15:04

Re: Figures de l'espace : placement des labels

Messagepar Fabrice » 15 Mai 2021 21:43

Bonsoir Patrick,
"L'idéal" serait effectivement que la figure soit la plus fidèle possible.
Merci.
Fabrice
Fabrice
 
Messages: 139
Inscription: 14 Août 2009 12:22


Revenir vers Questions - Réponses

Qui est en ligne ?

Utilisateurs parcourant ce forum : Aucun utilisateur inscrit et 18 invités

cron