Accentuer l'aspect de profondeur

N'oubliez pas de consulter les sujets avant de poser votre question, merci.

Accentuer l'aspect de profondeur

Messagepar Fabrice » 29 Déc 2015 18:44

Bonsoir Patrick,
Je dois illustrer un exercice avec une figure montrant une pièce métallique ayant la forme d'un pavé droit dans laquelle on perce un trou cylindrique de rayon 2cm et dont l'axe passe par le centre des faces ABFE et DCGH.
Est-il possible de donner un peu de "profondeur" au trou frontal ? (Je ne sais pas si je suis clair !)
Merci,
Fabrice

Code: Tout sélectionner
[view(-4,5.75,-4.75,4.5),Marges(0,0,0,0),size(9),
           Width:=10,
           a:=6,h:=4,
           A:=M(a,0,0),B:=M(a,a,0),C:=M(0,a,0),D:=Origin,
           E:=M(a,0,h),F:=M(a,a,h),G:=M(0,a,h),H:=M(0,0,h),
           centre:=bary3d([E,1,B,1]),
           hiddenLines:=1,
           piece:=Parallelep(D,A,C,H),
           cylindre:=Cylindre(centre,-a*vecI,1,65,0),
           section:=Section([A,vecI],piece),
           trou:=Clip3D(FacesNum(cylindre,1),section,1),
           Build3D(
           bdFacet(piece,[color:=white,border:=1]),
           bdCylinder(centre,-a*vecI,1,[color:=white,hollow:=1,border:=1,
                                         contrast:=0.4]),
           bdFacet(trou,[color:=white]),
           Display3D()),
           LabelDot3D(A,"A","S",0), LabelDot3D(C,"C","E",0),
           LabelDot3D(B,"B","S",0),LabelDot3D(D,"D","O",0),
           LabelDot3D(E,"E","N",0),LabelDot3D(F,"F","N",0),
           LabelDot3D(H,"H","N",0),LabelDot3D(G,"G","NE",0)
    ]                                                                                                                                 
Fabrice
 
Messages: 139
Inscription: 14 Août 2009 12:22

Re: Accentuer l'aspect de profondeur

Messagepar P.Fradin » 29 Déc 2015 19:25

Salut Fabrice,
Voilà ce que je peux te proposer:
Code: Tout sélectionner
[//command
    view(-4,5.75,-4.75,4.5),Marges(0,0,0,0),size(9),
    Width:=8,
    a:=6,h:=4,
    A:=M(a,0,0),B:=M(a,a,0),C:=M(0,a,0),D:=Origin,
    E:=M(a,0,h),F:=M(a,a,h),G:=M(0,a,h),H:=M(0,0,h),
    centre:=bary3d([E,1,B,1]),
    hiddenLines:=1,
    piece:=Parallelep(D,A,C,H),
    cylindre:=Cylindre(centre+vecI,-a*vecI,1,65,0), //cylindre décalé pour qu'il dépasse
    trou:=Clip3D(FacesNum(piece,6),cylindre,1), //on troue la face avant avec le cylindre décalé
    Build3D(
            bdFacet(FacesNum(piece,[1,2,3,4,5]),[color:=white,border:=1]), // les cinq faces normales
            bdCylinder(centre,-a*vecI,1,[color:=blue,hollow:=1,border:=1, // le cylindre normal
                                             contrast:=0.8]),
            bdFacet(trou,[color:=white]) // la face trouée
            ),
    Display3D(),
    Cercle3D(centre,1,vecI), //pour cacher les imperfections :)
    LabelDot3D(A,"A","S",0), LabelDot3D(C,"C","E",0),
    LabelDot3D(B,"B","S",0),LabelDot3D(D,"D","O",0),
    LabelDot3D(E,"E","N",0),LabelDot3D(F,"F","N",0),
    LabelDot3D(H,"H","N",0),LabelDot3D(G,"G","NE",0)
]

ParallepCylindreFab.png
ParallepCylindreFab.png (15.42 Kio) Consulté 6692 fois


J'ai mis le cylindre en bleu juste pour montrer que la face est effectivement trouée !
P.Fradin
Avatar de l’utilisateur
P.Fradin
Administrateur du site
 
Messages: 1887
Inscription: 29 Oct 2008 15:04

Re: Accentuer l'aspect de profondeur

Messagepar Fabrice » 30 Déc 2015 12:51

Bonjour Patrick,
Désolé pour la réponse tardive. Merci pour les améliorations apportées au code, TeXgraph permet de faire des figures assez réalistes.
Fabrice
Fabrice
 
Messages: 139
Inscription: 14 Août 2009 12:22

Re: Accentuer l'aspect de profondeur

Messagepar P.Fradin » 30 Déc 2015 17:38

Bonjour,

Suivant ce que l'on cherche, il n'est pas toujours nécessaire d'être forcément réaliste, on peut aussi tricher avec de la fausse 3D, par exemple ici, en dessinant un cylindre en pointillés par dessus le parallélépipède pour faire croire qu'il est à l'intérieur, et un disque peint en avant pour donner l'illusion d'un trou !
Code: Tout sélectionner
[   view(-4,5.75,-4.75,4.5),Marges(0,0,0,0),size(9),
    Width:=8,
    a:=6,h:=4,
    A:=M(a,0,0),B:=M(a,a,0),C:=M(0,a,0),D:=Origin,
    E:=M(a,0,h),F:=M(a,a,h),G:=M(0,a,h),H:=M(0,0,h),
    centre:=bary3d([E,1,B,1]),
    FillStyle:=full, Dparallelep(D,A,C,H,4), FillStyle:=none,
    LineStyle:=dotted,
    Ligne( Get(Dcylindre(centre,-a*vecI,1)), 0),
    LineStyle:=solid,
    FillStyle:=full, FillColor:=blue,
    Cercle3D(centre,1,vecI), //pour faire croire...
    LabelDot3D(A,"A","S",0), LabelDot3D(C,"C","E",0),
    LabelDot3D(B,"B","S",0),LabelDot3D(D,"D","O",0),
    LabelDot3D(E,"E","N",0),LabelDot3D(F,"F","N",0),
    LabelDot3D(H,"H","N",0),LabelDot3D(G,"G","NE",0)
]

ParallepCylindreFab2.png
ParallepCylindreFab2.png (14.61 Kio) Consulté 6684 fois

Et la fausse 3D fait parfois autant illusion que la vraie !
P.Fradin
Avatar de l’utilisateur
P.Fradin
Administrateur du site
 
Messages: 1887
Inscription: 29 Oct 2008 15:04


Revenir vers Questions - Réponses

Qui est en ligne ?

Utilisateurs parcourant ce forum : Aucun utilisateur inscrit et 18 invités

cron