Valeur absolue d'une fonction définie par des points

N'oubliez pas de consulter les sujets avant de poser votre question, merci.

Valeur absolue d'une fonction définie par des points

Messagepar Joffrey » 01 Oct 2014 21:52

Salut la communauté des Texgraphiens,

Je me sens un peu idiot devant le problème suivant :
Code: Tout sélectionner
\begin{texgraph}[name=fct_k,export=pgf,preload="grid.mod"]
Fenetre(-6+5.5*i,7-4.5*i,1.25+0.75*i),
Marges(0,0,0,0),
draw("grid",[-6-4.5*i,7+5.5*i],[nbsubdiv :=[1,1],gridcolor:=gray,gridstyle:=userdash,gridwidth:=2,
                            subgridcolor:=gray,subgridstyle:=userdash,subgridwidth:=2]),
draw("axeX",[0,1],[limits:=-7+7*i,Arrows:=1,originpos:=left]),
draw("axeY",[0,1],[limits:=-5+5.5*i,Arrows:=1,originpos:=jump]),
// fct f
L:=[-5-4*i,-3-3*i,-1,2*i,1,3-2*i,5,6+3*i],
draw("path",[L,curve],[legend:="\courbe{}",labelpos:=1,labeldir:=East,LineStyle:=userdash]),
draw("dot",L,[DotStyle:=dot]),
// fct k
Lk:=[for z in L do Re(z)+abs(Im(z))*i od],
draw("path",[Lk,curve],[legend:="\courbe{k}",labelpos:=0.1,labeldir:=South,Color:=forestgreen]),
draw("dot",Lk,[DotStyle:=dot,Color:=forestgreen]),
\end{texgraph}


La liste L contient les coordonnées des points de la fonction $f$ ; la liste Lk contient les coordonnées des points de la fonction $k=|f|$.
Le fait de définir $f$ par un nuage de points et d'utiliser une spline pose un problème pour représenter $k$, comment puis-je faire pour représenter exactement $C_k$ ?

Merci

Joffrey
L'homme en noir fuyait à travers le désert, et le Pistoléro le suivait ...
Joffrey
 
Messages: 287
Inscription: 16 Juil 2009 17:05
Localisation: Vichy

Re: Valeur absolue d'une fonction définie par des points

Messagepar P.Fradin » 01 Oct 2014 22:20

Bonsoir Joffrey,

Tu peux changer la fin de ton code ainsi:
Code: Tout sélectionner
    // fct k
    Lk:=[for z in Get(Spline([0,L,0])) do Re(z)+abs(Im(z))*i od], //on récupère l'ensemble des points de la courbe
    DotLk:=[for z in L do Re(z)+abs(Im(z))*i od],
    draw("line",Lk,[legend:="\courbe{k}",labelpos:=0.1,labeldir:=South,Color:=forestgreen]),
    draw("dot",DotLk,[DotStyle:=dot,Color:=forestgreen]),

ValAbs.png
ValAbs.png (5.15 Kio) Consulté 5748 fois
P.Fradin
Avatar de l’utilisateur
P.Fradin
Administrateur du site
 
Messages: 1887
Inscription: 29 Oct 2008 15:04

Re: Valeur absolue d'une fonction définie par des points

Messagepar Joffrey » 01 Oct 2014 22:25

Et ben c'est nickel.
Toujours au top, Patrick !

Merci
L'homme en noir fuyait à travers le désert, et le Pistoléro le suivait ...
Joffrey
 
Messages: 287
Inscription: 16 Juil 2009 17:05
Localisation: Vichy


Revenir vers Questions - Réponses

Qui est en ligne ?

Utilisateurs parcourant ce forum : Aucun utilisateur inscrit et 13 invités

cron