Est ce que c'est pro

[Raoul n k]

Les valeurs de theta et phi etant de 360 et 80 resp, j'ai utilisé le code ci-dessous pour
produire un dessin. Est ce que c'est pro?

Code: Tout sélectionner

[
view(-4.3,4.3,-3.5,3.5),
Arc3D([-sqrt(5)*i,2],[0,0],[sqrt(5)*i,2],3,-1),
DrawPlan([[0,2],vecK],vecJ-5*vecI,8,7),
Color:=white,
for b from 2 to 3 step 0.01 do Arc3D([-i*sqrt(9-(b^2)),b],[0,b],[i*sqrt(9-(b^2)),b],sqrt(9-(b^2)),1,vecK) od,
Color:=black,
LineStyle:=dahed,
Arc3D([-sqrt(5)*i,2],[0,2],[sqrt(5)*i,2],sqrt(5),-1,vecK),
LineStyle:=solid,
Arc3D([-sqrt(5)*i,2],[0,0],[sqrt(5)*i,2],3,1),
Arc3D([-sqrt(5)*i,2],[0,2],[sqrt(5)*i,2],sqrt(5),1,vecK),
LineStyle:=dashed,
Arc3D([-sqrt(5)*i,2],[0,0],[sqrt(5)*i,2],3,-1),
Ligne3D([[0,-3],[0,3]],0),
Ligne3D([[-i*sqrt(5),2],[0,3]],0),
Ligne3D([[i*sqrt(5),2],[0,3]],0),
Ligne3D([[-i*sqrt(5),2],[0,-3]],0),
Ligne3D([[i*sqrt(5),2],[0,-3]],0)
]


[P.Fradin]

Il faudrait être plus précis, que cherchez-vous à représenter?

PS: pour mettre le code en valeur, utiliser les balises code (bouton du même nom au-dessus de la zone d'édition).

[P.Fradin]

Une proposition:

Code: Tout sélectionner

[    view(-4.3,4.3,-3.5,3.5), view3D(-4,4,-4,4,-4,4), Marges(0,0,0,0), size(9),
    theta:=0, phi:=80*deg,
    Build3D(
            bdPlan( [M(0,0,2),vecK], [color:=red, border:=1]),
            bdSphere(Origin, 3, [color:=skyblue, smooth:=1, border:=1]),
            bdCercle( M(0,0,2), sqrt(5),vecK, [width:=8])
            ),
    Display3D(),
    LineStyle:=dashed,
    Cercle3D( M(0,0,2), sqrt(5), vecK),
    Ligne3D([ [0,-3],[0,3], [-i*sqrt(5),2],[0,-3], [i*sqrt(5),2],[0,3] ],0)
    ]


sphere.png (54.02 Kio) Consulté 14186 fois

[Raoul n k]

c'est tres beau patrick mais pour une impression en degre de gris, il ne faudrais pas les couleurs de preference.
il y a aussi cette histoire de Build3D qui ne fonctionne pas tres bien chez. aidez-moi à voir tout cela merci d'avance.

[P.Fradin]

Tout d'abord, utilisez la version 1.94 minimum. On peut activer les niveaux de gris:

Code: Tout sélectionner

[    view(-4.3,4.3,-3.5,3.5), view3D(-4,4,-4,4,-4,4), Marges(0,0,0,0), size(9),
     theta:=0, phi:=80*deg, GrayScale(1),
     Build3D(
                bdPlan( [M(0,0,2),vecK], [color:=white, border:=1]),
                bdSphere(Origin, 3, [color:=cyan, contrast:=0.25, border:=1]),
                bdCercle( M(0,0,2), sqrt(5),vecK, [width:=8])
                ),
     Display3D(),
     LineStyle:=dashed,
     Cercle3D( M(0,0,2), sqrt(5), vecK),
     Ligne3D([ [0,-3],[0,3], [-i*sqrt(5),2],[0,-3], [i*sqrt(5),2],[0,3] ],0)
]


Export pgf:

raoul4.png (11 Kio) Consulté 14154 fois

[Raoul n k]

c'est géniale. esperant que 1.94 me delivrera

[Alphonse Capriani]

Sinon, ya la version 1.95 en test...

A ce sujet (d'ailleurs, on est en plein hors sujet!!) ya moyen de désinstaller la version 1.94 pour installer à la place la version 1.95?

[P.Fradin]

Sinon, ya la version 1.95 en test...

A ce sujet (d'ailleurs, on est en plein hors sujet!!) ya moyen de désinstaller la version 1.94 pour installer à la place la version 1.95?

Sous linux pour une installation locale:

Code: Tout sélectionner

uninstallTeXgraph


Sous linux pour une installation en root:

Code: Tout sélectionner

sudo uninstallTeXgraph


[Alphonse Capriani]

Ah ouais : c'est super simple!!!

Je vais faire ca : je n'utilise plus la version 1.94 depuis un moment...

[Joffrey]

Bonjour,

Décidément je déterre pas mal de vieux sujets en ce moment, est-il possible, sans passé par BuildD d'obtenir qu'avec le code suivant :

Code: Tout sélectionner

[view3D(-5,5,-5,5,-5,5), view(-5,5,-3.5,3.5),
theta:=30*deg, phi:=75*deg,
Marges(0,0,0,0), size(6),
boule:=Sphere(Origin,3),
plan:= [M(0,0,1.75), vecK],
I:= Intersection(plan, boule, D0),
DrawPlan([M(0,0,1.75), vecK],vecJ,7,7),
FillStyle:=bdiag,FillColor:=red,LineStyle:=noline,
Ligne3D(D0,1),
LineStyle:=solid, FillStyle:=none, HideStyle:=userdash, Color:=red,
DrawAretes(I,0), Color:=black,
DrawPlan([M(0,0,1.75), vecK],vecJ,7,7),
Dsphere(Origin, 3,0)
]

qui donne

sphere.png (8.53 Kio) Consulté 14047 fois

on puisse "jouer" sur la bordure du plan qui est derrière la boule de façon a ce que cette partie soit en pointillés.

Merci

[P.Fradin]

Bonjour,

Oui on peut en rusant comme ceci:

Code: Tout sélectionner

[   view3D(-5,5,-5,5,-5,5), view(-5,5,-3.5,3.5),
    theta:=30*deg, phi:=75*deg,
    Marges(0,0,0,0), size(6),
    boule:=Sphere(Origin,3),
    plan:= [M(0,0,1.75), vecK],
    I:= Intersection(plan, boule, D0),
    DrawPlan([M(0,0,1.75), vecK],vecJ,7,7),
    {astuce}
    FillStyle:=full, FillColor:=white, Cercle(0,3), FillStyle:=none,
    Dsphere(Origin, 3,0), DrawPlan([M(0,0,1.75), vecK],vecJ,7,7,2),
    LineStyle:=userdash, DrawPlan([M(0,0,1.75), vecK],vecJ,7,7),
    {fin d'astuce}
    FillStyle:=bdiag,FillColor:=red,LineStyle:=noline, Ligne3D(D0,1),
    LineStyle:=solid,FillStyle:=none, HideStyle:=userdash, Color:=red,
    DrawAretes(I,0)
]


sphereJoffrey.png (8.38 Kio) Consulté 14030 fois

[Joffrey]

Bonjour,

Bien vu pour l'astuce, je tente de dessiner ce qu'il y a sous le plan en pointillés voir morceaux en verts sur la figure ci-dessous.

test2.png (14.71 Kio) Consulté 13996 fois

Tout semble être dans la superposition des couches en traits plein et en pointillés mais j'obtiens des résultats ou soit tout est en pointillés soit tout est en traits pleins.
Vois-tu?

[P.Fradin]

Salut joffrey,

Là ça commence à faire bricolage!

Code: Tout sélectionner

[   view3D(-5,5,-5,5,-5,5), view(-5,5,-3.5,3.5),
        theta:=30*deg, phi:=75*deg,
        Marges(0,0,0,0), size(6),
        boule:=Sphere(Origin,3),
        plan:= [M(0,0,1.75), vecK],
        I:= Intersection(plan, boule, D0),
        {astuce}
        FillStyle:=full, FillColor:=white, Cercle(0,3),
        Dsphere(Origin, 3,0), DrawPlan([M(0,0,1.75), vecK],vecJ,7,7),
        Arc(2.5+1.78*i,0,-2.5+1.78*i,3,1),
        LineStyle:=userdash, FillStyle:=none,
        Dsphere(Origin, 3,0),DrawPlan([M(0,0,1.75), vecK],vecJ,7,7),
        {fin d'astuce}
        FillStyle:=bdiag,FillColor:=red,LineStyle:=noline, Ligne3D(D0,1),
        LineStyle:=solid,FillStyle:=none, HideStyle:=userdash, Color:=red,
        DrawAretes(I,0)
    ]


sphereJoffrey2.png (8.41 Kio) Consulté 13990 fois

[P.Fradin]

Et sans faire de bricolage:

Code: Tout sélectionner

[
    view3D(-5,5,-5,5,-5,5), view(-5,5,-3.5,3.5),
    theta:=30*deg, phi:=75*deg,
    Marges(0,0,0,0), size(6),
    boule:=Sphere(Origin,3.01), plan:= [M(0,0,1.75), vecK], I:= Intersection(plan, boule),
    hiddenLines:=1, HideStyle:=userdash,
    Build3D(
                bdPlan(plan, [color:=white, contrast:=0, border:=1, scale:=0.7]),
                bdSphere(Origin, 3, [color:=white, contrast:=0.125, border:=1]),
                bdLine(I, [color:=red])
                ),
    Display3D()
]


sphereJoffrey3.png (11.07 Kio) Consulté 13984 fois

[projetmbc]

Bonjour,
peut-on aussi hachurer le disque ?

[P.Fradin]

Bonjour,
peut-on aussi hachurer le disque ?

Oui, mais par dessus la scène uniquement:

Code: Tout sélectionner

[   view3D(-5,5,-5,5,-5,5), view(-5,5,-3.5,3.5),
        theta:=30*deg, phi:=75*deg,
        Marges(0,0,0,0), size(6),
        boule:=Sphere(Origin,3.01),
        plan:= [M(0,0,1.75), vecK],
        I:= Intersection(plan, boule, D0),
        hiddenLines:=1, HideStyle:=userdash,
        Build3D(
                bdPlan( plan, [color:=white, contrast:=0, border:=1, scale:=0.7]),
                bdSphere( Origin, 3, [color:=white,contrast:=0.125,border:=1]),

                bdLine( I, [color:=red])
                ),
        Display3D(),
        FillStyle:=bdiag,FillColor:=red,LineStyle:=noline, Ligne3D(D0,1)
]


sphereJoffrey4.png (12.12 Kio) Consulté 13973 fois

[projetmbc]

Merci.

[Joffrey]

Re, je rajoute le grand cercle :

Code: Tout sélectionner

[   view3D(-5,5,-5,5,-5,5), view(-5,5,-3.5,3.5),
        theta:=30*deg, phi:=75*deg,
        Marges(0,0,0,0), size(6),
        boule:=Sphere(Origin,3.01),
        plan:= [M(0,0,1.75), vecK],
        I:= Intersection(plan, boule, D0),
        hiddenLines:=1, HideStyle:=userdash,
        Build3D(
                bdPlan( plan, [color:=white, contrast:=0, border:=1, scale:=0.7]),
                bdSphere( Origin, 3, [color:=white,contrast:=0,border:=1]),

                bdLine( I, [color:=red]),
                bdCercle(M(0,0,0),3,vecK)
                ),
        Display3D(),
        FillStyle:=bdiag,FillColor:=red,LineStyle:=noline, Ligne3D(D0,1)
]

[projetmbc]

Une question à la c-- mais j'assume. Quel est le fichier teg correspondant, ou mieux où doit-on mettre le code précédent relativement à l'interface de TeXgraph ? On ne se moque pas, je commence à peine à m'intéresser concrètement à TeXgraph (il était temps mais j'attendais aussi la nouvelle spécification des fichiers teg...).

[P.Fradin]

Les codes qui sont donnés sont à copier dans un élément graphique Utilisateur. On crée un tel élément avec la combinaison Ctrl+U (ou en cliquant sur le bouton où figurent des outils sur la barre Standard).

Sinon le fichier source est là:

Code: Tout sélectionner

TeXgraph#
{version 1.95-beta-10}
Cmd  [Fenetre(-5+3.5*i,5-3.5*i,0.6+0.6*i), Marges(0,0,0,0), Border(0)];
     [OriginalCoord(1),IdMatrix()];
     [theta:=0.5236, phi:=1.309, IdMatrix3D(), ModelView(ortho)];
     [GrayScale(0), ComptGraph:=2];

Graph objet1 = [view3D(-5,5,-5,5,-5,5), view(-5,5,-3.5,3.5),
           theta:=30*deg, phi:=75*deg,
           Marges(0,0,0,0), size(6),
           boule:=Sphere(Origin,3.01),
           plan:= [M(0,0,1.75), vecK],
           I:= Intersection(plan, boule, D0),
           hiddenLines:=1, HideStyle:=dotted,
           Build3D(
                   bdPlan( plan, [color:=white, contrast:=0, border:=1, scale:=0.7]),
                   bdSphere( Origin, 3, [color:=white,contrast:=0.125,border:=1]),
                   bdCercle(M(0,0,0),3,vecK),
                   bdLine( Merge3d(I), [color:=red])
                   ),
           Display3D(),
           FillStyle:=bdiag,FillColor:=red,LineStyle:=noline, Ligne3D(D0,1)
   ];


[projetmbc]

Merci pour cette précision.

[Alphonse Capriani]

J'ai pas du tout suivi le sujet, mais ca fait plaisir de voir que Joffrey a un peu plus de temps à consacrer à TeXgraph et au forum.

Tu nous manquais mec!
(au fait Patrick : la veuve de Samuel fait la gueule depuis que t'as oublié de poser un pot de chrysanthème sur sa pierre tombale à la Toussaint)

[Edit] : Je suis sur que personne ici aurait pensé qu'un jour le mot chrysanthème apparaîtrait sur le forum...