Est ce que c'est pro

N'oubliez pas de consulter les sujets avant de poser votre question, merci.

Est ce que c'est pro

Messagepar Raoul n k » 17 Août 2010 22:36

Les valeurs de theta et phi etant de 360 et 80 resp, j'ai utilisé le code ci-dessous pour
produire un dessin. Est ce que c'est pro?

Code: Tout sélectionner
[
view(-4.3,4.3,-3.5,3.5),
Arc3D([-sqrt(5)*i,2],[0,0],[sqrt(5)*i,2],3,-1),
DrawPlan([[0,2],vecK],vecJ-5*vecI,8,7),
Color:=white,
for b from 2 to 3 step 0.01 do Arc3D([-i*sqrt(9-(b^2)),b],[0,b],[i*sqrt(9-(b^2)),b],sqrt(9-(b^2)),1,vecK) od,
Color:=black,
LineStyle:=dahed,
Arc3D([-sqrt(5)*i,2],[0,2],[sqrt(5)*i,2],sqrt(5),-1,vecK),
LineStyle:=solid,
Arc3D([-sqrt(5)*i,2],[0,0],[sqrt(5)*i,2],3,1),
Arc3D([-sqrt(5)*i,2],[0,2],[sqrt(5)*i,2],sqrt(5),1,vecK),
LineStyle:=dashed,
Arc3D([-sqrt(5)*i,2],[0,0],[sqrt(5)*i,2],3,-1),
Ligne3D([[0,-3],[0,3]],0),
Ligne3D([[-i*sqrt(5),2],[0,3]],0),
Ligne3D([[i*sqrt(5),2],[0,3]],0),
Ligne3D([[-i*sqrt(5),2],[0,-3]],0),
Ligne3D([[i*sqrt(5),2],[0,-3]],0)
]
Dernière édition par P.Fradin le 18 Août 2010 10:17, édité 2 fois.
Raison: Ajout des balises code
Raoul n k
 
Messages: 40
Inscription: 13 Juil 2010 21:13

Re: Est ce que c'est pro

Messagepar P.Fradin » 17 Août 2010 23:57

Il faudrait être plus précis, que cherchez-vous à représenter?

PS: pour mettre le code en valeur, utiliser les balises code (bouton du même nom au-dessus de la zone d'édition).
P.Fradin
Avatar de l’utilisateur
P.Fradin
Administrateur du site
 
Messages: 1836
Inscription: 29 Oct 2008 15:04

Re: Est ce que c'est pro

Messagepar P.Fradin » 18 Août 2010 11:35

Une proposition:

Code: Tout sélectionner
[    view(-4.3,4.3,-3.5,3.5), view3D(-4,4,-4,4,-4,4), Marges(0,0,0,0), size(9),
    theta:=0, phi:=80*deg,
    Build3D(
            bdPlan( [M(0,0,2),vecK], [color:=red, border:=1]),
            bdSphere(Origin, 3, [color:=skyblue, smooth:=1, border:=1]),
            bdCercle( M(0,0,2), sqrt(5),vecK, [width:=8])
            ),
    Display3D(),
    LineStyle:=dashed,
    Cercle3D( M(0,0,2), sqrt(5), vecK),
    Ligne3D([ [0,-3],[0,3], [-i*sqrt(5),2],[0,-3], [i*sqrt(5),2],[0,3] ],0)
    ]


sphere.png
sphere.png (54.02 Kio) Consulté 13054 fois
P.Fradin
Avatar de l’utilisateur
P.Fradin
Administrateur du site
 
Messages: 1836
Inscription: 29 Oct 2008 15:04

Re: Est ce que c'est pro

Messagepar Raoul n k » 24 Août 2010 11:42

c'est tres beau patrick mais pour une impression en degre de gris, il ne faudrais pas les couleurs de preference.
il y a aussi cette histoire de Build3D qui ne fonctionne pas tres bien chez. aidez-moi à voir tout cela merci d'avance.
Raoul n k
 
Messages: 40
Inscription: 13 Juil 2010 21:13

Re: Est ce que c'est pro

Messagepar P.Fradin » 24 Août 2010 11:58

Tout d'abord, utilisez la version 1.94 minimum. On peut activer les niveaux de gris:

Code: Tout sélectionner
[    view(-4.3,4.3,-3.5,3.5), view3D(-4,4,-4,4,-4,4), Marges(0,0,0,0), size(9),
     theta:=0, phi:=80*deg, GrayScale(1),
     Build3D(
                bdPlan( [M(0,0,2),vecK], [color:=white, border:=1]),
                bdSphere(Origin, 3, [color:=cyan, contrast:=0.25, border:=1]),
                bdCercle( M(0,0,2), sqrt(5),vecK, [width:=8])
                ),
     Display3D(),
     LineStyle:=dashed,
     Cercle3D( M(0,0,2), sqrt(5), vecK),
     Ligne3D([ [0,-3],[0,3], [-i*sqrt(5),2],[0,-3], [i*sqrt(5),2],[0,3] ],0)
]


Export pgf:

raoul4.png
raoul4.png (11 Kio) Consulté 13022 fois
P.Fradin
Avatar de l’utilisateur
P.Fradin
Administrateur du site
 
Messages: 1836
Inscription: 29 Oct 2008 15:04

Re: Est ce que c'est pro

Messagepar Raoul n k » 24 Août 2010 15:29

c'est géniale. esperant que 1.94 me delivrera
Raoul n k
 
Messages: 40
Inscription: 13 Juil 2010 21:13

Re: Est ce que c'est pro

Messagepar Alphonse Capriani » 24 Août 2010 16:51

Sinon, ya la version 1.95 en test...

A ce sujet (d'ailleurs, on est en plein hors sujet!!) ya moyen de désinstaller la version 1.94 pour installer à la place la version 1.95?
Ya Ba Da Ba Dooo!!!
Avatar de l’utilisateur
Alphonse Capriani
 
Messages: 576
Inscription: 18 Juil 2009 19:10
Localisation: East Harlem - NY

Re: Est ce que c'est pro

Messagepar P.Fradin » 24 Août 2010 17:39

Alphonse Capriani a écrit:Sinon, ya la version 1.95 en test...

A ce sujet (d'ailleurs, on est en plein hors sujet!!) ya moyen de désinstaller la version 1.94 pour installer à la place la version 1.95?


Sous linux pour une installation locale:
Code: Tout sélectionner
uninstallTeXgraph


Sous linux pour une installation en root:

Code: Tout sélectionner
sudo uninstallTeXgraph
P.Fradin
Avatar de l’utilisateur
P.Fradin
Administrateur du site
 
Messages: 1836
Inscription: 29 Oct 2008 15:04

Re: Est ce que c'est pro

Messagepar Alphonse Capriani » 25 Août 2010 16:01

Ah ouais : c'est super simple!!!

Je vais faire ca : je n'utilise plus la version 1.94 depuis un moment...
Ya Ba Da Ba Dooo!!!
Avatar de l’utilisateur
Alphonse Capriani
 
Messages: 576
Inscription: 18 Juil 2009 19:10
Localisation: East Harlem - NY

Re: Est ce que c'est pro

Messagepar Joffrey » 05 Déc 2010 12:58

Bonjour,

Décidément je déterre pas mal de vieux sujets en ce moment, est-il possible, sans passé par BuildD d'obtenir qu'avec le code suivant :
Code: Tout sélectionner
[view3D(-5,5,-5,5,-5,5), view(-5,5,-3.5,3.5),
theta:=30*deg, phi:=75*deg,
Marges(0,0,0,0), size(6),
boule:=Sphere(Origin,3),
plan:= [M(0,0,1.75), vecK],
I:= Intersection(plan, boule, D0),
DrawPlan([M(0,0,1.75), vecK],vecJ,7,7),
FillStyle:=bdiag,FillColor:=red,LineStyle:=noline,
Ligne3D(D0,1),
LineStyle:=solid, FillStyle:=none, HideStyle:=userdash, Color:=red,
DrawAretes(I,0), Color:=black,
DrawPlan([M(0,0,1.75), vecK],vecJ,7,7),
Dsphere(Origin, 3,0)
]

qui donne
sphere.png
sphere.png (8.53 Kio) Consulté 12915 fois

on puisse "jouer" sur la bordure du plan qui est derrière la boule de façon a ce que cette partie soit en pointillés.

Merci
L'homme en noir fuyait à travers le désert, et le Pistoléro le suivait ...
Joffrey
 
Messages: 286
Inscription: 16 Juil 2009 17:05
Localisation: Vichy

Re: Est ce que c'est pro

Messagepar P.Fradin » 05 Déc 2010 14:57

Bonjour,

Oui on peut en rusant comme ceci:

Code: Tout sélectionner
[   view3D(-5,5,-5,5,-5,5), view(-5,5,-3.5,3.5),
    theta:=30*deg, phi:=75*deg,
    Marges(0,0,0,0), size(6),
    boule:=Sphere(Origin,3),
    plan:= [M(0,0,1.75), vecK],
    I:= Intersection(plan, boule, D0),
    DrawPlan([M(0,0,1.75), vecK],vecJ,7,7),
    {astuce}
    FillStyle:=full, FillColor:=white, Cercle(0,3), FillStyle:=none,
    Dsphere(Origin, 3,0), DrawPlan([M(0,0,1.75), vecK],vecJ,7,7,2),
    LineStyle:=userdash, DrawPlan([M(0,0,1.75), vecK],vecJ,7,7),
    {fin d'astuce}
    FillStyle:=bdiag,FillColor:=red,LineStyle:=noline, Ligne3D(D0,1),
    LineStyle:=solid,FillStyle:=none, HideStyle:=userdash, Color:=red,
    DrawAretes(I,0)
]


sphereJoffrey.png
sphereJoffrey.png (8.38 Kio) Consulté 12898 fois
P.Fradin
Avatar de l’utilisateur
P.Fradin
Administrateur du site
 
Messages: 1836
Inscription: 29 Oct 2008 15:04

Re: Est ce que c'est pro

Messagepar Joffrey » 07 Déc 2010 14:16

Bonjour,

Bien vu pour l'astuce, je tente de dessiner ce qu'il y a sous le plan en pointillés voir morceaux en verts sur la figure ci-dessous.
test2.png
test2.png (14.71 Kio) Consulté 12864 fois

Tout semble être dans la superposition des couches en traits plein et en pointillés mais j'obtiens des résultats ou soit tout est en pointillés soit tout est en traits pleins.
Vois-tu?
L'homme en noir fuyait à travers le désert, et le Pistoléro le suivait ...
Joffrey
 
Messages: 286
Inscription: 16 Juil 2009 17:05
Localisation: Vichy

Re: Est ce que c'est pro

Messagepar P.Fradin » 07 Déc 2010 14:46

Salut joffrey,

Là ça commence à faire bricolage!

Code: Tout sélectionner
[   view3D(-5,5,-5,5,-5,5), view(-5,5,-3.5,3.5),
        theta:=30*deg, phi:=75*deg,
        Marges(0,0,0,0), size(6),
        boule:=Sphere(Origin,3),
        plan:= [M(0,0,1.75), vecK],
        I:= Intersection(plan, boule, D0),
        {astuce}
        FillStyle:=full, FillColor:=white, Cercle(0,3),
        Dsphere(Origin, 3,0), DrawPlan([M(0,0,1.75), vecK],vecJ,7,7),
        Arc(2.5+1.78*i,0,-2.5+1.78*i,3,1),
        LineStyle:=userdash, FillStyle:=none,
        Dsphere(Origin, 3,0),DrawPlan([M(0,0,1.75), vecK],vecJ,7,7),
        {fin d'astuce}
        FillStyle:=bdiag,FillColor:=red,LineStyle:=noline, Ligne3D(D0,1),
        LineStyle:=solid,FillStyle:=none, HideStyle:=userdash, Color:=red,
        DrawAretes(I,0)
    ]


sphereJoffrey2.png
sphereJoffrey2.png (8.41 Kio) Consulté 12858 fois
P.Fradin
Avatar de l’utilisateur
P.Fradin
Administrateur du site
 
Messages: 1836
Inscription: 29 Oct 2008 15:04

Re: Est ce que c'est pro

Messagepar P.Fradin » 07 Déc 2010 15:03

Et sans faire de bricolage:

Code: Tout sélectionner
[
    view3D(-5,5,-5,5,-5,5), view(-5,5,-3.5,3.5),
    theta:=30*deg, phi:=75*deg,
    Marges(0,0,0,0), size(6),
    boule:=Sphere(Origin,3.01), plan:= [M(0,0,1.75), vecK], I:= Intersection(plan, boule),
    hiddenLines:=1, HideStyle:=userdash,
    Build3D(
                bdPlan(plan, [color:=white, contrast:=0, border:=1, scale:=0.7]),
                bdSphere(Origin, 3, [color:=white, contrast:=0.125, border:=1]),
                bdLine(I, [color:=red])
                ),
    Display3D()
]


sphereJoffrey3.png
sphereJoffrey3.png (11.07 Kio) Consulté 12852 fois
P.Fradin
Avatar de l’utilisateur
P.Fradin
Administrateur du site
 
Messages: 1836
Inscription: 29 Oct 2008 15:04

Re: Est ce que c'est pro

Messagepar projetmbc » 07 Déc 2010 17:43

Bonjour,
peut-on aussi hachurer le disque ?
projetmbc
 
Messages: 398
Inscription: 26 Déc 2009 18:01

Re: Est ce que c'est pro

Messagepar P.Fradin » 07 Déc 2010 18:08

projetmbc a écrit:Bonjour,
peut-on aussi hachurer le disque ?


Oui, mais par dessus la scène uniquement:

Code: Tout sélectionner
[   view3D(-5,5,-5,5,-5,5), view(-5,5,-3.5,3.5),
        theta:=30*deg, phi:=75*deg,
        Marges(0,0,0,0), size(6),
        boule:=Sphere(Origin,3.01),
        plan:= [M(0,0,1.75), vecK],
        I:= Intersection(plan, boule, D0),
        hiddenLines:=1, HideStyle:=userdash,
        Build3D(
                bdPlan( plan, [color:=white, contrast:=0, border:=1, scale:=0.7]),
                bdSphere( Origin, 3, [color:=white,contrast:=0.125,border:=1]),

                bdLine( I, [color:=red])
                ),
        Display3D(),
        FillStyle:=bdiag,FillColor:=red,LineStyle:=noline, Ligne3D(D0,1)
]


sphereJoffrey4.png
sphereJoffrey4.png (12.12 Kio) Consulté 12841 fois
P.Fradin
Avatar de l’utilisateur
P.Fradin
Administrateur du site
 
Messages: 1836
Inscription: 29 Oct 2008 15:04

Re: Est ce que c'est pro

Messagepar projetmbc » 07 Déc 2010 20:33

Merci.
projetmbc
 
Messages: 398
Inscription: 26 Déc 2009 18:01

Re: Est ce que c'est pro

Messagepar Joffrey » 07 Déc 2010 21:11

Re, je rajoute le grand cercle :
Code: Tout sélectionner
[   view3D(-5,5,-5,5,-5,5), view(-5,5,-3.5,3.5),
        theta:=30*deg, phi:=75*deg,
        Marges(0,0,0,0), size(6),
        boule:=Sphere(Origin,3.01),
        plan:= [M(0,0,1.75), vecK],
        I:= Intersection(plan, boule, D0),
        hiddenLines:=1, HideStyle:=userdash,
        Build3D(
                bdPlan( plan, [color:=white, contrast:=0, border:=1, scale:=0.7]),
                bdSphere( Origin, 3, [color:=white,contrast:=0,border:=1]),

                bdLine( I, [color:=red]),
                bdCercle(M(0,0,0),3,vecK)
                ),
        Display3D(),
        FillStyle:=bdiag,FillColor:=red,LineStyle:=noline, Ligne3D(D0,1)
]
L'homme en noir fuyait à travers le désert, et le Pistoléro le suivait ...
Joffrey
 
Messages: 286
Inscription: 16 Juil 2009 17:05
Localisation: Vichy

Re: Est ce que c'est pro

Messagepar projetmbc » 07 Déc 2010 21:35

Une question à la c-- mais j'assume. Quel est le fichier teg correspondant, ou mieux où doit-on mettre le code précédent relativement à l'interface de TeXgraph ? On ne se moque pas, je commence à peine à m'intéresser concrètement à TeXgraph (il était temps mais j'attendais aussi la nouvelle spécification des fichiers teg...).
projetmbc
 
Messages: 398
Inscription: 26 Déc 2009 18:01

Re: Est ce que c'est pro

Messagepar P.Fradin » 07 Déc 2010 22:20

Les codes qui sont donnés sont à copier dans un élément graphique Utilisateur. On crée un tel élément avec la combinaison Ctrl+U (ou en cliquant sur le bouton où figurent des outils sur la barre Standard).

Sinon le fichier source est là:
Code: Tout sélectionner
TeXgraph#
{version 1.95-beta-10}
Cmd  [Fenetre(-5+3.5*i,5-3.5*i,0.6+0.6*i), Marges(0,0,0,0), Border(0)];
     [OriginalCoord(1),IdMatrix()];
     [theta:=0.5236, phi:=1.309, IdMatrix3D(), ModelView(ortho)];
     [GrayScale(0), ComptGraph:=2];

Graph objet1 = [view3D(-5,5,-5,5,-5,5), view(-5,5,-3.5,3.5),
           theta:=30*deg, phi:=75*deg,
           Marges(0,0,0,0), size(6),
           boule:=Sphere(Origin,3.01),
           plan:= [M(0,0,1.75), vecK],
           I:= Intersection(plan, boule, D0),
           hiddenLines:=1, HideStyle:=dotted,
           Build3D(
                   bdPlan( plan, [color:=white, contrast:=0, border:=1, scale:=0.7]),
                   bdSphere( Origin, 3, [color:=white,contrast:=0.125,border:=1]),
                   bdCercle(M(0,0,0),3,vecK),
                   bdLine( Merge3d(I), [color:=red])
                   ),
           Display3D(),
           FillStyle:=bdiag,FillColor:=red,LineStyle:=noline, Ligne3D(D0,1)
   ];
P.Fradin
Avatar de l’utilisateur
P.Fradin
Administrateur du site
 
Messages: 1836
Inscription: 29 Oct 2008 15:04

Re: Est ce que c'est pro

Messagepar projetmbc » 07 Déc 2010 22:56

Merci pour cette précision.
projetmbc
 
Messages: 398
Inscription: 26 Déc 2009 18:01

Re: Est ce que c'est pro

Messagepar Alphonse Capriani » 07 Déc 2010 23:33

J'ai pas du tout suivi le sujet, mais ca fait plaisir de voir que Joffrey a un peu plus de temps à consacrer à TeXgraph et au forum.

Tu nous manquais mec!
(au fait Patrick : la veuve de Samuel fait la gueule depuis que t'as oublié de poser un pot de chrysanthème sur sa pierre tombale à la Toussaint)

[Edit] : Je suis sur que personne ici aurait pensé qu'un jour le mot chrysanthème apparaîtrait sur le forum... :lol:
Ya Ba Da Ba Dooo!!!
Avatar de l’utilisateur
Alphonse Capriani
 
Messages: 576
Inscription: 18 Juil 2009 19:10
Localisation: East Harlem - NY


Revenir vers Questions - Réponses

Qui est en ligne ?

Utilisateurs parcourant ce forum : Aucun utilisateur inscrit et 2 invités

cron