intersection cone plan

N'oubliez pas de consulter les sujets avant de poser votre question, merci.

intersection cone plan

Messagepar debimax » 20 Mars 2010 17:17

Bonjour

Je débute avec texgraph depuis une 1 semaine.
J' essaye d'obtenir l'intersection entre des plans et un cone (un disque dans mon cas).

À partir d'exemple de la doc et sur le net j'arrive à obtenir le bord (cercle) mais pas le disque.

Voila ce que j'essaye
Code: Tout sélectionner
cone:= Cone(M(0,0,-3), 6*vecK,4, 25,0),
Dcone(M(0,0,-3), 6*vecK,4, 25)  ,

plan0:= [M(0,0,-1), -2*vecK],
S0:= Intersection(plan0, cone),
DrawPlan(plan0,vecI,5,4),

plan1:= [ Origin, -2*vecK],
S1:= Intersection(plan1, cone),
DrawPlan(plan1,vecI,-6,6),

plan2:= [M(0,0,2), -2*vecK],
S2:= Intersection(plan2, cone),
DrawPlan(plan2,vecI,8,7.5),
Width:=8,
Color:= red,
DrawAretes(S0)   ,
DrawAretes(S1)   ,
DrawAretes(S2)             


DrawFacet(S0) ne donne rien de plus ?


J'ai aussi d'autre questions mais peut être est il préférable que je crée d'autre post?
-> Où trouve t on les sources ? (Ca me permettra éventuellement de rajouter deux ou trois choses dans la barre des menus).
-> Je n'ai pas vu de doc pour la création de macro (c'est pour cet été alors il y a le temps)

Je n'ai pas encore compris la méthode pour obtenir des figures3D et je regrette que la complétion ne soit pas aussi performante que sur d'autre logiciel (je pense à xcas par exemple) mais en pratiquant un peu j'espère que cela me deviendra plus familier.


merci encore.
debimax
 
Messages: 13
Inscription: 20 Mars 2010 16:25

Re: intersection cone plan

Messagepar P.Fradin » 20 Mars 2010 18:15

Bonjour,

La macro Intersection renvoie, si on le demande, la facette dans une variable.

Il y a deux types de 3D: "fil de fer" (c'est à l'utilisateur de gérer l'affichage des différents objets) ou "scene3d" (c'est le programme qui gère l'affichage des objets). Cela donne par exemple ceci:

Code: Tout sélectionner
[
    cone:= Cone(M(0,0,-3), 6*vecK,4, 45,0),
    plan0:= [M(0,0,-1), -2*vecK],
    S0:= Intersection(plan0, cone, D0),
    plan1:= [ Origin, -2*vecK],
    S1:= Intersection(plan1, cone, D1),
    plan2:= [M(0,0,2), -2*vecK],
    S2:= Intersection(plan2, cone, D2),
    Width:=8,
    Color:=black,
    DrawPlan(plan0,vecI,5,4), LineStyle:=noline, DrawFlatFacet(D0, [color:=cyan]),
    LineStyle:=solid, DrawPlan(plan1,vecI,-6,6), LineStyle:=noline, DrawFlatFacet(D1, [color:=cyan, LineStyle:=noline]),
    LineStyle:=solid, DrawPlan(plan2,vecI,8,7.5), LineStyle:=noline, DrawFlatFacet(D2, [color:=cyan, LineStyle:=noline]),
    LineStyle:=solid, Dcone(M(0,0,-3), 6*vecK,4, 25),
    Color:= red, DrawAretes([S0,S1,S2])
]


cone1.png
cone1.png (29.03 Kio) Consulté 4314 fois


on voit que la représentation du dernier plan est fausse, elle devrait être en partie cachée. Ou bien en scène3d:

Code: Tout sélectionner
[
    cone:= Cone(M(0,0,-3), 6*vecK,4, 45,0),
    plan0:= [M(0,0,-1), -2*vecK], S0:= Intersection(plan0, cone),
    plan1:= [ Origin, -2*vecK], S1:= Intersection(plan1, cone),
    plan2:= [M(0,0,2), -2*vecK], S2:= Intersection(plan2, cone),
    Build3D(
            bdPlan(plan0, [color:=blue, opacity:=0.7, scale:=0.75]),
            bdPlan(plan1, [color:=green, opacity:=0.7, scale:=0.75]),
            bdPlan(plan2, [color:=red, opacity:=0.7, scale:=0.75]),
            bdLine( Merge3d([S0,S1,S2]), [width:=8]),
            bdCone(M(0,0,-3), 6*vecK,4, [color:=slategray, contrast:=0.125, border:=1, opacity:=0.7])
            ),
    Display3D()
]


cone2.png
cone2.png (31.32 Kio) Consulté 4314 fois


J'ai aussi d'autre questions mais peut être est il préférable que je crée d'autre post?
-> Où trouve t on les sources ? (Ca me permettra éventuellement de rajouter deux ou trois choses dans la barre des menus).


Les sources sont dans l'archive (licence GPL oblige!), dans le sous-dossier src.

-> Je n'ai pas vu de doc pour la création de macro (c'est pour cet été alors il y a le temps)


En principe il y a tout ce qu'il faut dans la doc, en tout cas pour la théorie! Après il faut pratiquer, alors pour avoir des exemples on peut regarder les macros des différents fichiers de macros comme: TeXgraph.mac, scene3d.mac, ..., ils sont dans le sous-dossier macros (attention à ne pas les modifier!). Et puis surtout, il y a le forum!

Je n'ai pas encore compris la méthode pour obtenir des figures3D et je regrette que la complétion ne soit pas aussi performante que sur d'autre logiciel (je pense à xcas par exemple) mais en pratiquant un peu j'espère que cela me deviendra plus familier.


J'espère que l'exemple ci-dessus apportera un peu de lumière.
P.Fradin
Avatar de l’utilisateur
P.Fradin
Administrateur du site
 
Messages: 1887
Inscription: 29 Oct 2008 15:04

Re: intersection cone plan

Messagepar debimax » 20 Mars 2010 23:18

merci beaucoup :)

Il ne me reste plus qu'à bien étudier tes deux exemples pour mieux comprendre.

Merci encore
debimax
 
Messages: 13
Inscription: 20 Mars 2010 16:25


Revenir vers Questions - Réponses

Qui est en ligne ?

Utilisateurs parcourant ce forum : Aucun utilisateur inscrit et 8 invités

cron