Utiliser povray dans LateX?

Exemples avec export povray

Utiliser povray dans LateX?

Messagepar P.Fradin » 17 Mai 2011 22:16

Pour les dessins 3D relativement complexes, povray est un outil tout à fait adapté, c'est pour cela qu'à été fait le modèle povray.mod. Pour les inconditionnels du source du graphique dans le document LaTeX, voici comment utiliser l'export povray sur un exemple:
Code: Tout sélectionner
\begin{texgraph}[name=hyperboloide,auto=false,file]
 Include "povray.mod";
 Graph image=[
   view(-5,5,-5,5),Marges(0,0,0,0), size(8), theta:=45*deg, phi:=60*deg,
   view3D(-5,5,-5,5,-5,5), m:=sqrt(2), background(full, lightgray),
   povScene(
   povImplicit( pow(x/m,2)+pow(y/m,2)-pow(z/m,2)-1,  [clip:=1, clipwin:=[M(-5,-5,-3),M(5,5,3)], color:=slategray]),
        view3D(-10,10,-10,10,-3.5,3.5),
        for t from -pi to pi step 0.1 do
            povDroite( [-i*exp(i*t)*m,0, exp(i*t),1],  [width:=8, color:=crimson]),
            sep3D
        od,
        view3D(-5,5,-5,5,-5,5),
        povAxes(Origin, [arrows:=1, newxlegend("x"),  newylegend("y"),newzlegend("z")]),
        )];

 Cmd povray("hyperboloide",[imagescale:=1.125]);
\end{texgraph}
\includegraphics[width=8cm]{hyperboloide.png}

On désactive l'inclusion automatique (auto=false), on charge le modèle povray.mod, on crée un élément graphique mais l'instruction finale habituelle Display3D() est inutile ici pour l'export povray. On termine par une commande qui consiste a appeler la macro povray(...) avec le nom de l'image et son échelle (on grossit un peu) , c'est cette macro qui appelle le programme povray avec les options qui vont bien. Après l'environnement texgraph on inclut "à la main" l'image produite en ramenant sa taille à celle désirée au départ. Voici ce que l'on voit dans le fichier pdf (compilé avec pdflatex):
hyperboloide.png
hyperboloide.png (181.2 Kio) Consulté 29659 fois
P.Fradin
Avatar de l’utilisateur
P.Fradin
Administrateur du site
 
Messages: 1887
Inscription: 29 Oct 2008 15:04

Revenir vers Exemples povray

Qui est en ligne ?

Utilisateurs parcourant ce forum : Aucun utilisateur inscrit et 1 invité

cron