Bonjour Patrick,
Je n'arrive pas à faire une figure enfin un morceau,
je n'arrive pas à gérer la perspective sur la figure suivante :
Peux tu me tuyauter ?
Merci
Bon ça risque d'être une figure un peu pénible à faire...
[
view(-6,4,-6,5), Marges(0,0,0,0), size(9),
H:=7, h:=7, R:=3, eau:=H-2, haut:=2, r:=1.5, Width:=8,
hiddenLines:=0,HideStyle:=userdash,
Dcylindre(M(0,0,-eau),H*vecK,R,1),
Dcylindre(M(0,0,-eau),eau*vecK,R,1), Width:=6,
Build3D(
bdCylinder(M(0,0,-eau),eau*vecK,R, [border:=1,contrast:=0.125,color:=pink,opacity:=0.6,hollow:=0]),
bdCylinder(M(0,0,0),(H-eau)*vecK,R, [contrast:=0.5,color:=white, opacity:=0.3]),
bdCylinder(M(0,0,-eau+haut),h*vecK,r, [contrast:=0.5,color:=whitesmoke]),
bdCercle(M(0,0,H-eau), R, vecK, [hiddenLines:=1]),
bdCercle(M(0,0,0), R, vecK, [hiddenLines:=1])
),
Display3D(),
Dcylindre(M(0,0,-eau+haut),h*vecK,r,0),
Dcylindre(M(0,0,0),(h+haut-eau)*vecK,r,0),
A:=(h+haut-eau)*vecK, B:=A+r*ScreenX(),
LabelSeg(Proj3D(A), Proj3D(B), "$5\,$cm", [Arrows:=2, Color:=red, labelsep:=0.5]),
decal:=1,
A:=Origin+(r+decal)*ScreenX(),
B:=A-(eau-haut)*vecK,
LabelSeg(Proj3D(A), Proj3D(B),"$h$",[Arrows:=2, Color:=red, rotation:=0]),
LineStyle:=userdash, Color:=red,
Ligne3D([A,A-decal*ScreenX(),jump,B,B-decal*ScreenX()],0),
A:=Origin-(R+decal)*ScreenX(),
B:=A-vecK,
Ligne3D([A,A+decal*ScreenX(),jump,B,B+decal*ScreenX()],0),
LineStyle:=solid,
LabelSeg(Proj3D(A), Proj3D(B),"$2$\,cm",[Arrows:=2, Color:=red, rotation:=0, labelpos:=bottom, LabelStyle:=right])
]
Revenir vers Géométrie de l'espace
Utilisateurs parcourant ce forum : Aucun utilisateur inscrit et 8 invités