Page 1 sur 1

Théorème de Varignon dans l'espace

MessagePublié: 13 Juin 2011 08:53
par Eric
Bonjour Patrick

Je souhaiterais reproduire la figure attachée. Il s'agit d'un octaèdre (pas nécessairement régulier) v_ij, i=1,2,3, j=0 ou 1, deux sommets formant une diagonale s'ils ont le même premier indice. On ajoute à cela un parallélépipède dont les sommets sont les centres de gravité des faces de l'octaèdre (w_{i1i2i3} est le centre de gravité de la face v_ji_j, j=1,2,3).

Varignon.JPG
Copyright MAA, 2009
Varignon.JPG (40.11 Kio) Consulté 7716 fois


Comment produire une telle figure ?

Merci d'avance,
Eric

Re: Théorème de Varignon dans l'espace

MessagePublié: 13 Juin 2011 12:07
par P.Fradin
Salut Eric,

Je te propose ceci (je suis parti du principe que les deux solides sont convexes):
Code: Tout sélectionner
[
view(-4,4,-4.5,4.5), Marges(0,0,0,0), size(9), viewDir(35,80),
Z:=3, d:=4,
V10:=M(d,0,Z), V31:=M(0,d,Z), V20:=M(-d,-d,Z),
V21:=M(d,d,-Z), V11:=M(-d,0,-Z), V30:=M(0,-d,-Z),
W000:=isobar3d([V10,V20,V30]), W001:=isobar3d([V10,V20,V31]),
W010:=isobar3d([V10,V21,V30]), W011:=isobar3d([V10,V21,V31]),
W100:=isobar3d([V11,V20,V30]), W101:=isobar3d([V11,V20,V31]),
W110:=isobar3d([V11,V21,V30]), W111:=isobar3d([V11,V21,V31]),
Sp:=[W000,W001,W010,W011,W100,W101,W110,W111],
So:=[V10,V11,V20,V21,V30,V31],
P:=Cvx3d(Sp), octaedron:=Cvx3d(So),
octaedron2:=[V10,V31,V20,jump,V30,V21,V10,jump,V21,V11,V31,jump,
            V21,V30,V11,jump,V31,V11,V20,jump,V20,V11,V30,jump,V10,V20,V30,jump],
Build3D(
        bdFacet(octaedron2, [color:=steelblue, opacity:=0.8]),
        bdFacet( P, [color:=lightgray, opacity:=0.6]),
        bdLine(Merge3d(Aretes(P)), [width:=12]),
        bdLine(Merge3d(Aretes(octaedron)), [width:=12]),
        bdDot(So, [dotstyle:=cube, dotscale:=0.5, color:=slategray]),
        bdDot(Sp, [dotstyle:=cube, dotscale:=0.5, color:=crimson])
       ),
Display3D(), LabelSize:=scriptsize,
LabelDot3D(V10,"$V_{10}$","O"), LabelDot3D(V11,"$V_{11}$","E"),
LabelDot3D(V20,"$V_{20}$","N"), LabelDot3D(V21,"$V_{21}$","S"),
LabelDot3D(V30,"$V_{30}$","O"), LabelDot3D(V31,"$V_{31}$","N"),
Color:=red,
LabelDot3D(W000,"$W_{000}$","O"), LabelDot3D(W001,"$W_{001}$","N"),
LabelDot3D(W010,"$W_{010}$","O"), LabelDot3D(W011,"$W_{011}$","E"),
LabelDot3D(W100,"$W_{100}$","N"), LabelDot3D(W101,"$W_{101}$","E"),
LabelDot3D(W110,"$W_{110}$","S"), LabelDot3D(W111,"$W_{111}$","E")
]

Varignon.png
Varignon.png (30.08 Kio) Consulté 7703 fois

Re: Théorème de Varignon dans l'espace

MessagePublié: 13 Juin 2011 12:13
par Eric
Je te remercie, je vais regarder ta proposition de près (mais elle me plait déjà beaucoup ;)).

La convexité n'est pas nécessaire, le théorème reste vrai dans tous les cas (comme dans le plan), mais la figure est plus lisible dans ce cas.

Re: Théorème de Varignon dans l'espace

MessagePublié: 18 Nov 2011 18:28
par Eric
Je suis en train de conclure (envoi chez l'imprimeur sous peu). J'ai recadré et j'ai repassé la figure en gris mais l'éditeur me dit qu'elle est encore trop foncée. Sur quels paramètre puis-je jouer ?

Merci d'avance,
Eric

Varignon.teg
(1.97 Kio) Téléchargé 775 fois

Re: Théorème de Varignon dans l'espace

MessagePublié: 18 Nov 2011 19:17
par P.Fradin
Bonsoir Eric,

Tu peux jouer sur le contraste pour les facettes (j'ai mis 0.25 au lieu de 1) et l'épaisseur pour le arêtes (j'ai mis 10 au lieu de 12):
Code: Tout sélectionner
[
    view(-4,4,-4.5,4.5), Marges(0,0,0,0), size(9), viewDir(35,80),
    Z:=3, d:=4,
    V10:=M(d,0,Z), V31:=M(0,d,Z), V20:=M(-d,-d,Z),
    V21:=M(d,d,-Z), V11:=M(-d,0,-Z), V30:=M(0,-d,-Z),
    W000:=isobar3d([V10,V20,V30]), W001:=isobar3d([V10,V20,V31]),
    W010:=isobar3d([V10,V21,V30]), W011:=isobar3d([V10,V21,V31]),
    W100:=isobar3d([V11,V20,V30]), W101:=isobar3d([V11,V20,V31]),
    W110:=isobar3d([V11,V21,V30]), W111:=isobar3d([V11,V21,V31]),
    Sp:=[W000,W001,W010,W011,W100,W101,W110,W111],
    So:=[V10,V11,V20,V21,V30,V31],
    P:=Cvx3d(Sp), octaedron:=Cvx3d(So),
    octaedron2:=[V10,V31,V20,jump,V30,V21,V10,jump,V21,V11,V31,jump,
                V21,V30,V11,jump,V31,V11,V20,jump,V20,V11,V30,jump,V10,V20,V30,jump],
    Build3D(
            bdFacet(octaedron2, [color:=white, contrast:=0.25, opacity:=0.8]),
            bdFacet( P, [color:=whitesmoke, contrast:=0.25, opacity:=0.7]),
            bdLine(Merge3d(Aretes(P)), [width:=10]),
            bdLine(Merge3d(Aretes(octaedron)), [width:=10]),
            bdDot(So, [dotstyle:=cube, dotscale:=0.5, color:=black]),
            bdDot(Sp, [dotstyle:=cube, dotscale:=0.5, color:=black])
           ),
    Display3D(), LabelSize:=scriptsize,
    LabelDot3D(V10,"$V_{10}$","O"), LabelDot3D(V11,"$V_{11}$","E"),
    LabelDot3D(V20,"$V_{20}$","N"), LabelDot3D(V21,"$V_{21}$","S"),
    LabelDot3D(V30,"$V_{30}$","O"), LabelDot3D(V31,"$V_{31}$","N"),
    LabelDot3D(W000,"$W_{000}$","O"), LabelDot3D(W001,"$W_{001}$","N"),
    LabelDot3D(W010,"$W_{010}$","O"), LabelDot3D(W011,"$W_{011}$","E"),
    LabelDot3D(W100,"$W_{100}$","N"), LabelDot3D(W101,"$W_{101}$","E"),
    LabelDot3D(W110,"$W_{110}$","S"), LabelDot3D(W111,"$W_{111}$","E")
]

Varignon2.png
Varignon2.png (14.59 Kio) Consulté 7583 fois

Re: Théorème de Varignon dans l'espace

MessagePublié: 18 Nov 2011 19:36
par Eric
Je te remercie Patrick

Exactement ce qu'il me fallait !