Page 1 sur 1

Dessin embarrassant

MessagePublié: 17 Août 2010 23:37
par Raoul n k
Je veux déssiner avec texgraph une espèce de CUBE CREUSE DE FACON QU'ON PUISSE INSERER DANS CHACUNE DE 3 DE SES FACES UNE DEMI POME.
voici ce que j'ai éssayé;vous aller comprendre ce que je veux dire.

Code: Tout sélectionner
[
Dparallelep([-2-2*i,-2],4*vecI,4*vecJ,4*vecK,0),
for k from 0 to 2*pi step pi/12 do Ligne3D([Origin,[2*cos(k)+2*i,2*sin(k)]],0),Ligne3D([Origin,[2+2*i*cos(k),2*sin(k)]],0) od,
Cercle3D([2,0],2,vecI),Cercle3D([2*i,0],2,vecJ)
]


Et le mien n'est pas beau; aidez-moi PARDON.

Re: Dessin embarrassant

MessagePublié: 17 Août 2010 23:49
par P.Fradin
Qu'entendez-vous par demi-pomme? Une demi-sphère?

Je regarderai tout ça demain matin.

Re: Dessin embarrassant

MessagePublié: 18 Août 2010 10:43
par P.Fradin
Ne sachant pas trop ce que vous souhaitez, voici deux propositions:

Code: Tout sélectionner
[
Marges(0,0,0,0), size(9),
Build3D(
        bdCone( Origin, 2*vecK, 2, [color:=cyan, contrast:=0.125, border:=1]),
        bdCone( Origin, 2*vecI, 2, [color:=cyan, contrast:=0.125, border:=1]),
        bdCone( Origin, 2*vecJ, 2, [color:=cyan, contrast:=0.125, border:=1]),
        ),
Display3D(),
Dparallelep([-2-2*i,-2],4*vecI,4*vecJ,4*vecK)
]


raoul1.png
raoul1.png (18.64 Kio) Consulté 10173 fois


Code: Tout sélectionner
[
Marges(0,0,0,0), size(9),
P:=Parallelep([-2-2*i,-2],4*vecI,4*vecJ,4*vecK), S:=Sphere(Origin, 2),
demiS:=ClipFacet(S, [Origin, vecI]),
Build3D(
        bdFacet( P, [color:=steelblue, border:=1]),
        bdFacet(demiS, [matrix:=[M(2,0,0), vecI,vecJ,vecK], color:=crimson, contrast:=0.125]),
        bdFacet(demiS, [matrix:=[M(0,2,0),vecJ,-vecI,vecK], color:=crimson, contrast:=0.125]),
        bdFacet(demiS, [matrix:=[M(0,0,2), vecK,vecJ,-vecI], color:=crimson, contrast:=0.125]),
        ),
Display3D()
]


raoul2.png
raoul2.png (20.78 Kio) Consulté 10177 fois

Re: Dessin embarrassant

MessagePublié: 19 Août 2010 16:33
par Alphonse Capriani
Je suis ravi de voir que le forum a accueilli un nouveau membre qui à vraiment l'air de vouloir se mettre à TeXgraph.

Cela dit Raoul, désolé de faire le rabat-joie, mais ce serait mieux si tu pouvais être plus précis dans tes posts : on a du mal à savoir ce que tu veux. Non seulement ca te permettrait d'avoir des réponses d'une meilleure qualité, ca permettrait aussi à Patrick d'éviter de bosser sur un dessin qui ne sera probablement pas celui attendu (j'admire ton courage et ta patience Patrick!!)...

Désolé d'être si casse c... (Faut que j'arrête mes conneries : je vais faire fuire les nouveaux arrivants...)

Re: Dessin embarrassant

MessagePublié: 23 Août 2010 19:13
par Raoul n k
merci beaujcoup; le premier dessin ressemble à ça mais j'aivais voulu que le cube soit de coleur et que les zones reserves pour les demi spheres soit blanches; je veux aussi voir a l'interieur de ces des arcs 3D de couleur noir uniformement repartis.

Re: Dessin embarrassant

MessagePublié: 23 Août 2010 22:46
par P.Fradin
Là par contre c'est plus technique, il faut carrément découper les trois faces. Par contre je ne comprends toujours vos histoires de demi-sphère et d'arc, alors que dans votre figure initiale ce sont des cônes que vous avez dessinés!

Code: Tout sélectionner
[
    Marges(0,0,0,0), size(9),
    FillStyle:=full, FillColor:=steelblue,
    Lfacet:=[M(2,-2,-2),
      for k from 0 to 24 do
          rot3d(M(2,0,-2), [Origin,vecI],-k*pi/12),
      od,
      M(2,2,-2),M(2,2,2),M(2,-2,2)],
    Rfacet:=[M(2,2,-2),
      for k from 0 to 24 do
          rot3d(M(0,2,-2), [Origin,vecJ],-k*pi/12),
      od,
      M(-2,2,-2),M(-2,2,2),M(2,2,2)],
    Tfacet:=[M(2,2,2),
      for k from 0 to 24 do
          rot3d(M(0,2,2), [Origin,vecK],-k*pi/12),
      od,
      M(-2,2,2),M(-2,-2,2),M(2,-2,2)],
    C1:=Cone( Origin, 2*vecI, 2),
    C2:=Cone( Origin, 2*vecJ, 2),
    C3:=Cone( Origin, 2*vecK, 2),

    DrawFacet( [C1,C2,C3], [color:=lightgray]),
    DrawFacet([Rfacet,jump,Tfacet,jump,Lfacet,jump], [color:=steelblue]),
    Dparallelep([-2-2*i,-2],4*vecI,4*vecJ,4*vecK)
    ]


raoul3.png
raoul3.png (47.92 Kio) Consulté 10124 fois

Re: Dessin embarrassant

MessagePublié: 24 Août 2010 11:28
par Raoul n k
bon bon on est arrivé à ce que je voulais mais j'ai une préoccupation. j'ai texgraph 1.93 le code fourni pour la création du 1er dessin ne m'a fournit que le cube; less zones de couleur ayant disparu. merci deja pour ce que j'ai recopié là et merci de dire pourquoi je n'ai pas obtenu le 1er dessin.

Re: Dessin embarrassant

MessagePublié: 24 Août 2010 11:36
par P.Fradin
La version 1.93 est obsolète. La dernière version stable est la 1.94, il y a aussi la prochaine version 1.95 en test.

Re: Dessin embarrassant

MessagePublié: 24 Août 2010 15:20
par Raoul n k
Merci beaucoup M. p. Fra j'ai pris 1.94 aujourd'hui je vais essayé avec elle.