les figures que j'utilise pour mes cours (ici TS)

les figures que j'utilise pour mes cours (ici TS)

Messagepar debimax » 27 Mars 2010 12:53

bonjour

voici les figures que je compléterai au fur et mesure de mon cours de ts
J'utilise la dernière version (instable) de texgraph pour écrire les vecteurs avec latex pour les fichiers de geomview (ou javaview d'ailleur) ce qui me permet en même temps que j'écris mon cours de montrer les figures3d avec geomview.
edit je n'ai pas (encore) compris comment mettre toutes les images sur un même post alors je un post par image.


Code: Tout sélectionner
[
view(-5,5,-3,3),Marges(0,0,0,0),
A:=M(0,0,-2), B:=M(0,0,2), C:=M(2,-2,0), H:=M(0,0,0),
  MU:=M(0,0,-1) ,  MV:=M(1,-1,-1) ,
  plan0:= [H, vecK] ,
    droite:=[H,2*vecK ],
   lineAB:= [A,B],
   TeXify:=1 ,
    Build3D( bdDroite(droite, [color:=blue,opacity:=0.6]),
    bdLine(lineAB ,[color:=red, arrows:=1, width:=30])  ,
    bdLine( [A,C] ,[color:=red, arrows:=1, width:=30]) ,
    bdLine( [C,H] ,[color:=red, arrows:=0, width:=30]) ,
    bdPlan(plan0, [color:=lightcyan, opacity:=0.5,border:=1, contrast:=0.125,scale:=0.75]),
    bdDot([A,B,C,H], [ dotscale:=2,color:=forestgreen]),
     bdAngleD(B,H,C, 0.3) ,
    bdLabel(B,"B",[labelpos:=[-0.3*i,i]]),
    bdLabel(H,"H",[labelpos:=[0.4+0.4*i,1]]),
    bdLabel(C,"C",[labelpos:=[0.4*i,3]]),
    bdLabel(A,"A",[labelpos:=[-0.4*i,i]]),
    bdLabel(MU,"\vec{u}",[labelpos:=[-0.4*i,i], ]),
    bdLabel(MV,"\vec{v}",[labelpos:=[-0.2+0.2*i,i]]),
    bdArc(C,A,H,0.8,1,[color:=black,arrows:=1, labelarc("\theta")]),

           { bdLine( Merge3d([S0,S1,S2]), [width:=8]),}
            ),
    Display3D()

]

pdt-scalaire3.png
pdt-scalaire3.png (10.17 Kio) Consulté 16521 fois


Code: Tout sélectionner
[
view(-5,5,-2,5),Marges(0,0,0,0),
A:=M(0,0,0), B:=M(0,0,3), C:=M(-1,-2.5,0), D:=M(2,2,0),
u:=vecK, v:=-0.7*vecI+1.4*vecJ,w:=-1.4*vecI-0.7*vecJ,
  plan0:= [A, vecK] ,
    droite1:=[A,u ], droite2:=[C,v],
   vec_u:= [B,B+1.5*u] ,vec_v:= [C,C+v], vec_w:=[C,C+w],
   vec_u':=[A,A+1.5*u] ,vec_v':= [A,A+v] , vec_w':=[A,A+w],
  { ,vec_vp:= [A,A-vecI+vecJ],
   vec_w:= [C,C+1.5*vecI-0.3*vecJ],vec_wp:= [A,A+1.5*vecI-0.3*vecJ],}
   TeXify:=1 ,
   Build3D(
    bdDroite(droite1, [color:=blue,opacity:=0.6]),
     bdDroite(droite2, [color:=blue,opacity:=0.6]),
    bdPlan(plan0, [color:=lightcyan, opacity:=0.5,border:=1, contrast:=0.125,scale:=0.75]),
    bdLine(vec_u ,[color:=green, arrows:=1, width:=30]),
    bdLine(vec_v ,[color:=green, arrows:=1, width:=30]),
    bdLine(vec_w ,[color:=green, arrows:=1, width:=30]),
    bdLine(vec_u' ,[color:=red, arrows:=1, width:=30]),
    bdLine(vec_v' ,[color:=red, arrows:=1, width:=30]),
    bdLine(vec_w' ,[color:=red, arrows:=1, width:=30]),
    bdAngleD(B,A,A+v, 0.3) ,
    bdAngleD(B,A,A+w, 0.3) ,
    bdLabel(B+0.8*vecK,"\vec{u}",[labelpos:=[0.3,-1]]),
    bdLabel(C+0.5*v,"\vec{v}",[labelpos:=[0.3,i]]),
    bdLabel(A+0.5*v,"\vec{v}",[labelpos:=[0.3,i]]),
    bdLabel(C+0.5*w,"\vec{w}",[labelpos:=[0.3,i]]),
    bdLabel(A+0.9*vecK,"\vec{u}",[labelpos:=[0.3,-1]]),
   ),
    Display3D()  ,
]                               


pdt-scalaire4.png
pdt-scalaire4.png (11.26 Kio) Consulté 16522 fois


Code: Tout sélectionner
[
view(-4.5,4.5,-2,2.5),Marges(0,0,0,0),
A:=M(0,0,0), B:=M(2,-2,0),
vec_n:=[A,A+2*vecK], vec_u:=[A,B],
 plan0:= [A, vecK] ,
   TeXify:=1 ,
   Build3D(
    bdPlan(plan0, [color:=lightcyan, opacity:=0.5,border:=1, contrast:=0.125,scale:=0.75]),
    bdLine(vec_u ,[color:=red, arrows:=0, width:=30]),
    bdLine(vec_n ,[color:=red, arrows:=1, width:=30]),
    bdAngleD(A+vecK,A,B, 0.3) ,
    bdDot([A, B],[dotscale:=5,color:=green]),
    bdLabel(A+vecK,"\vec{n}",[labelpos:=[0.3,1]]),
    bdLabel(A,"A",[labelpos:=[0.3,1]]),
    bdLabel(B,"M",[labelpos:=[0.3,i]]),
   ),
    Display3D()  ,
]


pdt-scalaire5.png
pdt-scalaire5.png (9.91 Kio) Consulté 16524 fois
Dernière édition par debimax le 27 Mars 2010 15:59, édité 2 fois.
debimax
 
Messages: 13
Inscription: 20 Mars 2010 16:25

Re: les figures que j'utilise pour mes cours (ici TS)

Messagepar P.Fradin » 27 Mars 2010 13:58

Bonjour debimax,

Et merci pour cette contribution. Tu peux mettre autant de fichiers joints que tu veux par message, il faut recliquer à chaque fois sur l'onglet fichier joint puis: parcourir, puis Ajouter le fichier, puis mettre en ligne.

Comment as-tu obenu tes aperçus? Je demande ça car ils n'ont pas l'air antialiasés. On peut avoir mieux:

debimax.png
debimax.png (12.93 Kio) Consulté 16539 fois


et

debimax2.png
debimax2.png (9.82 Kio) Consulté 16537 fois
P.Fradin
Avatar de l’utilisateur
P.Fradin
Administrateur du site
 
Messages: 1887
Inscription: 29 Oct 2008 15:04

Re: les figures que j'utilise pour mes cours (ici TS)

Messagepar debimax » 27 Mars 2010 14:52

P.Fradin a écrit:Bonjour debimax,

Et merci pour cette contribution. Tu peux mettre autant de fichiers joints que tu veux par message, il faut recliquer à chaque fois sur l'onglet fichier joint puis: parcourir, puis Ajouter le fichier, puis mettre en ligne.

Comment as-tu obenu tes aperçus? Je demande ça car ils n'ont pas l'air antialiasés. On peut avoir mieux:


solution de facilité avec imagemagick sur le fichier eps (ou pdf je ne sais plus) car je n'utilise pas de fichier png mais eps ou pstricks.

Je vais regarder pour tout mettre sur le 1° post.

merci


edit: j'ai vu pour la création du png capture au format png -> pdfc (me parait le mieux avec la version que j'ai)
Dernière édition par debimax le 27 Mars 2010 15:03, édité 1 fois.
debimax
 
Messages: 13
Inscription: 20 Mars 2010 16:25

Re: les figures que j'utilise pour mes cours (ici TS)

Messagepar P.Fradin » 27 Mars 2010 15:00

debimax a écrit:solution de facilité avec imagemagick sur le fichier eps (ou pdf je ne sais plus) car je n'utilise pas de fichier png mais eps ou pstricks.
Je vais regarder pour tout mettre sur le 1° post.
merci


Pour faire des aperçus tu as le bouton Snapshot dans l'interface graphique, il te demande quel type d'export tu veux (eps, epsc, pdf, pfdc, bmp), puis quel type de conversion tu veux ensuite (png, jpeg, résolution). et il te fait tout ça automatiquement. La conversion fait appel à ImageMagick mais avec des options adéquates ;) .
P.Fradin
Avatar de l’utilisateur
P.Fradin
Administrateur du site
 
Messages: 1887
Inscription: 29 Oct 2008 15:04

Re: les figures que j'utilise pour mes cours (ici TS)

Messagepar debimax » 27 Mars 2010 15:34

(Re)bonjour

C'est tout bon j'ai mis mes figures sur le 1° post et pour la création des png j'avais trouvé (voir l'édit du post précédent).
Pour les bonne options d'mage magick je n'avais pas le temps de regarder :mrgreen:

Puisque texgraph utilise imagemagick j'imagine que c'est pascal-magick qui est utilisé.
A l'occasion je regarderai les options utilisées.

@+ merci encore
debimax
 
Messages: 13
Inscription: 20 Mars 2010 16:25

Re: les figures que j'utilise pour mes cours (ici TS)

Messagepar P.Fradin » 27 Mars 2010 18:15

debimax a écrit:Puisque texgraph utilise imagemagick j'imagine que c'est pascal-magick qui est utilisé.
A l'occasion je regarderai les options utilisées.
@+ merci encore


TeXgraph n'utilise pas pascal-magick, il invoque simplement la commande convert d'ImageMagick qui doit donc être installé. La macro qui s'occupe des snapshots est dans le fichier interface.mac , la voici:

Code: Tout sélectionner
{Snapshot( type export, ecran/imprimante(0/1), nom, montrer (0/1) )}
[$rep:=%1, $show:= if %4=Nil then 1 else %4 fi,
if rep<>Nil then
   if (rep=eps) Or (rep=epsc) then
      Export(rep, [\TmpPath,"snapshot.eps"]),
      Exec(    if Windows then "cmd /C convert" else "convert" fi,
               [if %2 then "-density 600 -depth 8 -quality 75 " else "-density 300 -scale 32% -depth 8 -quality 100 " fi,
         "snapshot.eps ",%3], \TmpPath, (show=1)),
   elif (rep=pdf) Or (rep=pdfc) then
      Export(rep, [\TmpPath,"snapshot.pdf"]),
      Exec(    if Windows then "cmd /C convert" else "convert" fi,
               [if %2 then "-density 600 -depth 8 -quality 75 " else "-density 300 -scale 32% -depth 8 -quality 100 " fi,
         "snapshot.pdf ",%3], \TmpPath, (show=1))
   elif rep=bmp then
      Export(rep, [\TmpPath,"snapshot.bmp"]),
      Exec(    if Windows then "cmd /C convert" else "convert" fi, ["snapshot.bmp ",%3], \TmpPath, (show=1))
   fi,
if show=1 then Exec( if Windows then "cmd /C IMdisplay" else "display" fi,%3,\TmpPath,0)
else
Message(["L'utilitaire convert d'ImageMagick vient d'être lancé.",LF,
"La conversion demandée peut être longue,",LF,
"attendez l'apparition de l'image dans votre navigateur de fichiers,",LF,
"ou surveillez la date s'il existe déjà."])
fi
fi]
P.Fradin
Avatar de l’utilisateur
P.Fradin
Administrateur du site
 
Messages: 1887
Inscription: 29 Oct 2008 15:04

Re: les figures que j'utilise pour mes cours (ici TS)

Messagepar debimax » 02 Avr 2010 20:52

je continue mon 1° post

intersection cone-plan

Code: Tout sélectionner
[  TeXify:=1 ,   
 view3D( -5, 5, -5,5,-2, 6)  ,
 som:=M(0,0,0),I:=M(0,0,5),J:=M(0,4,5) ,
view(-7,7,-2,7),
    cone:= Cone(som, 5*vecK,4, 45,0),
    plan0:= [M(0,0,1.5), vecK],
    S0:= Intersection(plan0, cone, D0),
    plan1:= [ M(0,0,3), vecK],
    S1:= Intersection(plan1, cone, D1),
    plan2:=[M(0,0,4.99), vecK],
    S2:= Intersection(plan2, cone, D2),
    Color:=black,

    LineStyle:=solid,
     Build3D(
     bdFacet([D0,D1,D2],[color:=cyan,border:=1,bordercolor:=red]),
     bdLine([som,I],[color:=red]),
     bdCone(som,5*vecK,4, [opacity:=0.3]) ,
     bdPlan(plan0,[color:=white,opacity:=0.1, border:=1]),
     bdPlan(plan1,[color:=white,opacity:=0.1, border:=1]),
     bdPlan(plan2,[color:=white,opacity:=0.1, border:=1]),
     bdDot([som, I],[dotscale:=5,color:=black]),
     bdLabel(som,"O",[labelpos:=[0.3,1-i]]),
     bdLabel(I,"I",[labelpos:=[0.3,1+i]]),
     bdAxes(Origin,[ labels :=0]),
     bdLabel(M(5.3,0,0),"x"),
     bdLabel(M(0,5.3,0),"y"),
     bdLabel(M(0,0,6.3),"z"),
     ),
     Display3D(),



intersection-cone-plan.png
intersection-cone-plan.png (28.89 Kio) Consulté 16454 fois



intersection boule - plan

Code: Tout sélectionner
[
   TeXify:=1 ,
    view3D( -5, 5, -5,5,-4, 4)  ,
    view(-6,6,-5,5),
    som:=M(0,0,-3),I:=M(0,0,3),J:=M(0,4,3) ,
    boule:=Sphere(Origin,3),
    plan0:= [M(0,0,-1.5), vecK],
    S0:= Intersection(plan0, boule, D0),
    plan1:= [ Origin, vecK],
    S1:= Intersection(plan1, boule, D1),
    plan2:= [M(0,0,2), vecK],
    S2:= Intersection(plan2, boule, D2),
    Width:=8,
    Color:=black,
    LineStyle:=solid,
    Build3D(
    bdFacet([D0,D1,D2],[color:=cyan,border:=1,bordercolor:=red]),
    bdLine([som,I],[color:=red]),
    FillStyle:=none,
    bdSphere(Origin, 3, [opacity:=0.3]),
    bdCercle(Origin,3,vecI),
    bdPlan(plan0,[color:=white,opacity:=0.1, border:=1]),
    bdPlan(plan1,[color:=white,opacity:=0.1, border:=1]),
    bdPlan(plan2,[color:=white,opacity:=0.1, border:=1]),
    bdAxes(Origin, [labels :=0] ),
    bdLabel(M(5.3,0,0),"x") ,
    bdLabel(M(0,5.3,0),"y" ) ,
    bdLabel(M(0,0,4),"z", [labelpos :=[0.3,i ]] ) ,
    ),
    Display3D(),
    {Dsphere(Origin, 3,0),}
]


intersection-boule-plan.png
intersection-boule-plan.png (42.64 Kio) Consulté 16447 fois
Dernière édition par debimax le 19 Avr 2010 15:54, édité 1 fois.
debimax
 
Messages: 13
Inscription: 20 Mars 2010 16:25

Re: les figures que j'utilise pour mes cours (ici TS)

Messagepar P.Fradin » 02 Avr 2010 21:39

Bonsoir debimax,

Merci pour ta contribution. Je me permets quelques petites remarques:

* pour moins voir les facettes du cône on peut diminuer l'option contrast.
* marquer les bords du cône et ne pas le mettre de la même couleur que les plans.
* pourquoi ne pas utiliser de labels TeX? Ces figures passent sans problème en pgf.

Par exemple la première:

Code: Tout sélectionner
[   view3D( -5, 5, -5,5,-2, 6)  ,
    som:=M(0,0,0),I:=M(0,0,5),J:=M(0,4,5) , view(-7,7,-2,7),
        cone:= Cone(som, 5*vecK,4, 45,0),
        plan0:= [M(0,0,1.5), vecK],
        S0:= Intersection(plan0, cone, D0),
        plan1:= [ M(0,0,3), vecK],
        S1:= Intersection(plan1, cone, D1),
        plan2:=[M(0,0,4.99), vecK],
        S2:= Intersection(plan2, cone, D2),

         Build3D(
         bdFacet([D0,D1,D2],[color:=cyan,border:=1,bordercolor:=red]),
         bdLine([som,I],[color:=red,width:=12]),
         bdCone(som,5*vecK,4, [color:=lightcyan,opacity:=0.3, contrast:=0.25, border:=1]) ,
         bdPlan(plan0,[color:=white,opacity:=0.1, border:=1]),
         bdPlan(plan1,[color:=white,opacity:=0.1, border:=1]),
         bdPlan(plan2,[color:=white,opacity:=0.1, border:=1]),
         bdDot([som, I],[dotscale:=5,color:=black]),
         bdLabel(som,"$O$",[labelpos:=[0.3,1-i]]),
         bdLabel(I,"$I$",[labelpos:=[0.3,1+i]]),
         bdAxes(Origin,[ labels:=1, arrows:=1])
         ),
         Display3D(),
    ]


cone_plans.png
cone_plans.png (28.16 Kio) Consulté 16444 fois


Pour la sphère:

Code: Tout sélectionner
[
        view3D( -5, 5, -5,5,-4, 4)  ,  view(-6,6,-5,5),
        som:=M(0,0,-3),I:=M(0,0,3),J:=M(0,4,3) ,
        boule:=Sphere(Origin,3),
        plan0:= [M(0,0,-1.5), vecK],
        S0:= Intersection(plan0, boule, D0),
        plan1:= [ Origin, vecK],
        S1:= Intersection(plan1, boule, D1),
        plan2:= [M(0,0,2), vecK],
        S2:= Intersection(plan2, boule, D2),

        Build3D(
        bdFacet([D0,D1,D2],[color:=cyan,border:=1,bordercolor:=red]),
        bdLine([som,I],[color:=red, width:=12]),
        bdSphere(Origin, 3, [color:=lightcyan,opacity:=0.3,border:=1, contrast:=0.5]),
        bdPlan(plan0,[scale:=0.85, color:=white,opacity:=0.1, border:=1]),
        bdPlan(plan1,[scale:=0.85, color:=white,opacity:=0.1, border:=1]),
        bdPlan(plan2,[scale:=0.85, color:=white,opacity:=0.1, border:=1]),
        bdAxes(Origin, [labels:=1, arrows:=1] )
        ),
        Display3D()
    ]


sphere_plan.png
sphere_plan.png (30.28 Kio) Consulté 16438 fois


Bon, je sais, je chipote... :D
P.Fradin
Avatar de l’utilisateur
P.Fradin
Administrateur du site
 
Messages: 1887
Inscription: 29 Oct 2008 15:04

Re: les figures que j'utilise pour mes cours (ici TS)

Messagepar debimax » 02 Avr 2010 22:34

bonjour P.fradin
pour moins voir les facettes du cône on peut diminuer l'option contrast.
oui j'avais déjà testé, merci de me le rappeler.
* marquer les bords du cône et ne pas le mettre de la même couleur que les plans.

je suis aussi de ton avis
* pourquoi ne pas utiliser de labels TeX? Ces figures passent sans problème en pgf.

pgf j'en veux pas ;)
ensuite $z$ me pose problème avec l'export en jvx ou obj. Je vois sur la figure le symbole $
alors j'utilise pour l'instant l'option TeXify:=1

version texgraph 1.95 beta2
OS debian sid
version latex: texlive
debimax
 
Messages: 13
Inscription: 20 Mars 2010 16:25

Re: les figures que j'utilise pour mes cours (ici TS)

Messagepar P.Fradin » 02 Avr 2010 22:45

debimax a écrit:bonjour P.fradin


Appelle-moi Patrick!

pgf j'en veux pas ;)
ensuite $z$ me pose problème avec l'export en jvx ou obj. Je vois sur la figure le symbole $
alors j'utilise pour l'instant l'option TeXify:=1


Ah ok! Pour l'export javaview c'est effectivement l'option TeXify.
P.Fradin
Avatar de l’utilisateur
P.Fradin
Administrateur du site
 
Messages: 1887
Inscription: 29 Oct 2008 15:04


Revenir vers Géométrie de l'espace

Qui est en ligne ?

Utilisateurs parcourant ce forum : Aucun utilisateur inscrit et 11 invités

cron